啟動界面和載入等待 link

添加啟動界面 link

在遊戲啟動後進入菜單前,播放圖片或影片的界面稱作啟動界面(Splash Screen)。通常會在這個界面顯示Logo或開場動畫。 “splashscreen”腳本標籤會在主選單之前自動執行。因此,可以在遊戲腳本的任何地方使用這個標籤使用啟動界面。

如果要在遊戲啟動界面添加文本,可以在腳本中添加如下代碼(除了splashscreen標籤內部):

label splashscreen:
    scene black
    with Pause(1)

    show text "American Bishoujo Presents..." with dissolve
    with Pause(2)

    hide text with dissolve
    with Pause(1)

    return

啟動界面的另一個樣例,這次使用一張圖片和一段音訊:

image splash = "splash.png"

label splashscreen:
    scene black
    with Pause(1)

    play sound "ping.ogg"

    show splash with dissolve
    with Pause(2)

    scene black with dissolve
    with Pause(1)

    return

最後一個樣例,使用一段影片:

label splashscreen:

    $ renpy.movie_cutscene('movie.ogv')

    return

添加載入等待畫面 link

載入等待(presplash)是Ren’Py在載入腳本並啟動遊戲過程中顯示的畫面。 如果需要當引擎啟動後顯示載入等待畫面,值需要創建名為 presplash.pngpresplash.jpg 的圖片文件,保存到game目錄下就行了。

presplash.png
遊戲載入過程中顯示的圖片。

添加進度條 link

引擎自身載入完畢後,除了靜態圖片,還可以顯示一個載入進度條。 如果設置了載入進度條,會自動取代原來的載入等待畫面。

進度條可以更換主題,要求創作者提供兩張PNG或JPG格式的圖片:

presplash_background.png
進度條背景圖。整個啟動階段都會顯示,用作整個載入進度的背景。 這個圖往往是完全不透明的。
presplash_foreground.png
進度條前景圖。隨著載入進度從左往右逐漸顯示。該圖用於顯示實際的載入進度,可以包含一些透明度。

載入進度條的工作方式是,Ren’Py首先顯示 presplash_background.png ,接著在背景上覆蓋 presplash_foreground.png,並按載入進度從左往右逐步顯示。

進度條的主題效果完全由創作者決定,下面兩個樣例僅供參考:

_images/presplash_background_1.png

進度條背景圖樣例。

_images/presplash_foreground_1.png

進度條前景圖樣例。

_images/presplash_background_2.png

一個略精緻的進度條背景樣例。

_images/presplash_foreground_2.png

一個略精緻的進度條前景樣例。