游戏内菜单（新）

BuErShen

游戏内菜单（翻译：被诅咒的章鱼）

在许多视觉系小说中，用户会在被要求为故事情节的走向做出选择。Ren’Py脚本语言中包含了menu语句，使得向用户展现选项十分容易。

这里有个menu语句的样例：

[RenPy] 纯文本查看 复制代码

menu:
     "What should I do?"

     "Drink coffee.":
         "I drink the coffee, and it's good to the last drop."

     "Drink tea.":
         $ drank_tea = True

         "I drink the tea, trying not to make a political statement as I do."

     "Genuflect.":
         jump genuflect_ending

label after_menu:

     "After having my drink, I got on with my morning."

menu语句以关键词 menu 开头。后面可能跟着一个脚本标签(label)名，该文本标签(label)下的语句块可以被预处理为菜单选项。举例如下：

[RenPy] 纯文本查看 复制代码

menu drink_menu:
    ...

menu语句后面跟着一个缩进的语句块(block)。该语句块(block)可能包含一条 say语句 ，且必须包含至少一个菜单选项。若存在那条say语句，发言内容与菜单选项会同时在界面上显示。

菜单选项。 菜单选项是用户在游戏内菜单中的可选项。菜单选项以一个字符串开头。该字符串后面可能跟一个if分句。这个if分句增加了不同情况下的选项是否出现的功能。菜单选项以英文冒号结束，下面必须跟着一个Ren’Py语句块。

当某个选项被选中，该选项下对应的语句块(block)就会执行。执行到那个语句块结尾时，会跳转到menu语句结尾并执行之后的脚本。

if分句 包含关键词 if ，后面跟着一个python表达式。只有当表达式为True时，该菜单选项才会显示。例如下面的菜单中：

[RenPy] 纯文本查看 复制代码

menu:
    "Go left.":
        ...
    "Go right.":
        ...
    "Fly above." if drank_tea:
        ...

只有在 “the drank_tea” 变量为 True 时才显示第三个选项。