图片按钮问题

saasasa

怎么实现多个移动的图片，每个移动的图片都是一个图片按钮，并且点击一个图片按钮就只消除点击的那个图片按钮，
其他的继续移动，直到全部都点击过才能把所有移动的图片按钮全部消除。

龙氏

实现实现多个移动的图片，学习ATL变换，具体看这里：https://doc.renpy.cn/zh-CN/atl.html
或看这贴子：https://www.renpy.cn/forum.php?mod=viewthread&tid=242
图片按钮消除，点击按钮执行action就可以。

BuErShen

[RenPy] 纯文本查看 复制代码

###### 定义图片 ####
image tupian_a :
    "#ffff00"
    size(100,150)

image tupian_b :
    "#ff0000"
    size(100,100)

###### 定义：变换(transform)效果 ####
transform hello_1:
    align (0.5, 0.5)
    linear 1 pos (0.5, 0.2) alpha 0.3
    linear 1 pos (0.5, 0.5) alpha 1.0
    repeat # 循环 
 
transform hello_2:
    align (0.5, 1.0) 
    linear 2.0 align (0.5, 1.0) knot (0.0, .33) knot (1.0, .66)
    pause 0.5 # 暂停1秒
    repeat # 循环 

## 定义变量"club"，控制按钮隐藏。
default club = True

###### 定义：界面（screen） ####
screen aaa:
    if club:
        imagebutton:
            at hello_1
            idle "tupian_b" ##当按钮没有得到焦点状态时，使用在按钮上的图像。
            ## 省事，使用同一张图。
            hover "tupian_b" ##当按钮得到焦点状态时，使用在按钮上的图像。

            ## 由变量"club"，控制按钮隐藏。
            action SetVariable("club", False)

screen bbb:
    imagebutton:
        at hello_2
        idle "tupian_a" ##当按钮没有得到焦点状态时，使用在按钮上的图像。
        ## 省事，使用同一张图。
        hover "tupian_a" ##当按钮得到焦点状态时，使用在按钮上的图像。

        ## 直接隐藏整个screen，达到隐藏imagebutton
        action Hide ("bbb")

# 游戏在此开始。
label start:
    show screen aaa
    "已经显示aaa,点击会不会消失？"

    "aaa消失了吗？"
    show screen bbb
    "现在显示bbb,不容易点击到哦！"
    "bbb消失了吗？"

    "aaa和bbb用不同的隐藏方式，也可以使用{a=https://doc.renpy.cn/zh-CN/screens.html#call-screen}call screen{/a}显示。"

    # 此处为游戏结尾。
    return