请问renpy有办法实现角色血条吗？

13390163901

比如在屏幕最上行实现，一个条，随着hp/maxhp的比值减小而减小，谢谢大佬！

老司机飞飞飞

https://www.renpy.cn/forum.php?m ... &extra=page%3D1
看一下官方教程吧，里面有关于bar的用法

BuErShen

官方教程里的screen修改下：

[RenPy] 纯文本查看 复制代码

## 该screen显示信息，注意括号里的5个参数。
screen single_stat(name, hp, hp_max, lv, xalign):

    frame:
        xalign xalign # 位置，注意是相同的，不是常见X和Y。

        vbox:
            spacing 5

            hbox:
                text "[name!t]" min_width 220
                text _(" Lv. [lv]")

            hbox:
                text _("HP"):
                    min_width 40
                    yalign 0.5

                bar:
                    value AnimatedValue(hp, hp_max, 1.0)
                    xmaximum 180
                    ysize 26

                text " [hp]/[hp_max]":
                    yalign 0.5

# 此screen用use 入参方式，一次显示两个信息不同的single_stat。
screen stats():

    use single_stat(_("英雄"), hero_hp, hero_hp_max, hero_lv, 0.0)
    use single_stat(_("魔王"), Devil_hp, Devil_hp_max, Devil_lv, 1.0)

## 英雄 数值。
default hero_hp = 50
default hero_hp_max = 100
default hero_lv = 10

## 魔王 数值。
default Devil_hp = 100
default Devil_hp_max = 100
default Devil_lv = 90

# 游戏在此开始。
label start:

    show screen stats
    with dissolve

    "英雄需要治疗。"
    $ hero_hp = 100
    "治疗完成。"


    "魔王等级太高了？"
    $ Devil_lv = 10

    "现在都是10级了。"

    hide screen stats
    "关闭数值显示界面"

    # 此处为游戏结尾。
    return

13390163901

BuErShen 发表于 2019-11-5 23:08
官方教程里的screen修改下：
[mw_shl_code=renpy,true]## 该screen显示信息，注意括号里的5个参数。
screen ...

谢谢！！！！！！！！！！！！！！