RenPy中文空间

 找回密码
 立即注册

QQ登录

只需一步,快速开始

查看: 779|回复: 3

[已解决] 请问renpy有办法实现角色血条吗?

[复制链接]
发表于 2019-11-4 19:18:58 | 显示全部楼层 |阅读模式

马上注册,结交更多好友,享用更多功能,让你轻松玩转社区。

您需要 登录 才可以下载或查看,没有帐号?立即注册

x
比如在屏幕最上行实现,一个条,随着hp/maxhp的比值减小而减小,谢谢大佬!
发表于 2019-11-4 20:29:58 | 显示全部楼层
https://www.renpy.cn/forum.php?m ... &extra=page%3D1
看一下官方教程吧,里面有关于bar的用法
回复 支持 反对

使用道具 举报

发表于 2019-11-5 23:08:56 | 显示全部楼层
官方教程里的screen修改下:
[RenPy] 纯文本查看 复制代码
## 该screen显示信息,注意括号里的5个参数。
screen single_stat(name, hp, hp_max, lv, xalign):

    frame:
        xalign xalign # 位置,注意是相同的,不是常见X和Y。

        vbox:
            spacing 5

            hbox:
                text "[name!t]" min_width 220
                text _(" Lv. [lv]")

            hbox:
                text _("HP"):
                    min_width 40
                    yalign 0.5

                bar:
                    value AnimatedValue(hp, hp_max, 1.0)
                    xmaximum 180
                    ysize 26

                text " [hp]/[hp_max]":
                    yalign 0.5

# 此screen用use 入参方式,一次显示两个信息不同的single_stat。
screen stats():

    use single_stat(_("英雄"), hero_hp, hero_hp_max, hero_lv, 0.0)
    use single_stat(_("魔王"), Devil_hp, Devil_hp_max, Devil_lv, 1.0)

## 英雄 数值。
default hero_hp = 50
default hero_hp_max = 100
default hero_lv = 10

## 魔王 数值。
default Devil_hp = 100
default Devil_hp_max = 100
default Devil_lv = 90

# 游戏在此开始。
label start:

    show screen stats
    with dissolve

    "英雄需要治疗。"
    $ hero_hp = 100
    "治疗完成。"


    "魔王等级太高了?"
    $ Devil_lv = 10

    "现在都是10级了。"

    hide screen stats
    "关闭数值显示界面"

    # 此处为游戏结尾。
    return



回复 支持 反对

使用道具 举报

 楼主| 发表于 2019-11-6 12:02:17 | 显示全部楼层
BuErShen 发表于 2019-11-5 23:08
官方教程里的screen修改下:
[mw_shl_code=renpy,true]## 该screen显示信息,注意括号里的5个参数。
screen ...

谢谢!!!!!!!!!!!!!!
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|手机版|RenPy中文空间 ( 苏ICP备17067825号 | 苏公网安备 32092302000068号 )

GMT+8, 2020-12-3 18:25 , Processed in 0.031895 second(s), 12 queries , File On.

Powered by Discuz! X3.4 Licensed

Copyright © 2001-2020, Tencent Cloud.

快速回复 返回顶部 返回列表