关于拖放系统的求助

apoto5

想做一个拖放系统，把打乱排列的几样证物拖进对应的槽内才能推进剧情那种……有没有大神能指点一下看哪篇文章或者贴一点范例……我站内搜索没找到……

BuErShen

我来回答吧，
“拖放(Drag and Drop)”文档不知您看了没有?
https://doc.renpy.cn/zh-CN/drag_drop.html#drag-drop-examples
文档中有两个示例，其中第二个好像符合您的需求：
示例脚本如下：

[RenPy] 纯文本查看 复制代码

init python:
 
    def detective_dragged(drags, drop):
 
        if not drop:
            return
 
        store.detective = drags[0].drag_name
        store.city = drop.drag_name
 
        return True
screen send_detective_screen:
 
    # 地图作为背景。
    add "europe.jpg"
 
    # 一个DragGroup（拖放组）确保侦探和城市
    # 可以互相拖放。
    draggroup:
 
        # 我们的侦探。
        drag:
            drag_name "Ivy"
            child "ivy.png"
            droppable False
            dragged detective_dragged
            xpos 100 ypos 100
        drag:
            drag_name "Zack"
            child "zack.png"
            droppable False
            dragged detective_dragged
            xpos 150 ypos 100
 
        # 他们可以去的城市。
        drag:
            drag_name "London"
            child "london.png"
            draggable False
            xpos 450 ypos 140
        drag:
            drag_name "Paris"
            draggable False
            child "paris.png"
            xpos 500 ypos 280
label send_detective:
    "我们需要调查，我们应该派谁去，他们应该去哪里?"
 
    call screen send_detective_screen
 
    "好的，我们会派 [detective] 到 [city]."