[教程] renpy 图像处理器 例子

blackpineapple

演示效果


代码

[RenPy] 纯文本查看 复制代码

## 加颜色
image julian_2 = im.MatrixColor('julian.png', im.matrix.tint(.5, .1, .2))

## 模糊图片
image julian_3 = im.Blur("julian.png", 1.5)

## 水平或者垂直翻转
image julian_4 = im.Flip("julian.png", horizontal=True) # vertical=True

## im.Grayscale 灰度版本
image julian_5 = im.Grayscale("julian.png")

## im.Sepi 即老照片样式
image julian_6 = im.Sepia("julian.png")

## im.Tile 在 size 范围内以tile形式码放 im 。
image julian_7 = im.Tile(im.Crop("julian.png", (0, 0, 100, 100)), size=(1280, 720))
image julian_8 = im.Tile("julian.png", size=(1280, 720))

## 图像明度的变化值。该值是一个介于-1和1之间的数值。-1表示最低明度，1表示最高明度。
image julian_9 = im.MatrixColor(
    "julian.png",
    im.matrix.brightness(0.3))

## 这个矩阵能使图像黑色变为红色，而白色变为蓝色。
image julian_10 = im.MatrixColor(
    "julian.png",
    im.matrix.colorize("#f00", "#00f"))

## 对比度 0.0和1.0
image julian_11 = im.MatrixColor(
    "julian.png",
    im.matrix.contrast(0.3))

## im.matrix.hue 色相
image julian_12 = im.MatrixColor(
    "julian.png",
    im.matrix.hue(30))

## im.matrix.opacity 透明度  o 为0.0表示完全透明，为1.0表示完全不透明。

image julian_13 = im.MatrixColor(
    "julian.png",
    im.matrix.opacity(0.3))


label start():
    scene street day
    "今天来演示下图像处理器。"
    show julian_2 with dissolve
    "首先演示下改变图像的颜色。我们这里用立绘做例子，但是图像处理器也可以用在按钮的图片等地方。"
    hide julian_2 with dissolve
    show julian_3 with dissolve
    "现在的例子是图像模糊的效果。"
    hide julian_3 with dissolve
    show julian_4 with dissolve
    "还可以水平反转，或者垂直反转。"
    hide julian_4 with dissolve
    show julian_5 with dissolve
    "也可以获得图片的灰阶。"
    hide julian_5 with dissolve
    show julian_6 with dissolve
    "也可以获得老照片的样式。"
    hide julian_6 with dissolve
    show julian_8 with dissolve
    "也可以让一张图片，以这种几联的形式显示。"
    hide julian_8 with dissolve
    show julian_9 with dissolve
    "也可以修改图片的明度，这个功能还可以用来修改当按钮被按住的效果。"
    hide julian_9 with dissolve
    show julian_10 with dissolve
    "改变图片的颜色"
    hide julian_10 with dissolve
    show julian_11 with dissolve
    "修改图片对比度。"
    hide julian_11 with dissolve
    show julian_12 with dissolve
    "改变色相。"
    hide julian_12 with dissolve
    show julian_13 with dissolve
    "改变图片的透明度。"
    hide julian_13 with dissolve
    "这些图片处理效果可以通过组合做出不同的效果，也可以用于各种图片。"
    "这次的演示就到这里结束，感谢观看。"
    return