在Renpy中实现历史记录跳跃效果

丛雨

在许多Galgame中都有在历史记录点击历史对话跳跃的效果，让游玩者有更多操作自由。
通过修改screen history，可以实现此类效果。

[RenPy] 纯文本查看 复制代码

## 将screen history中 window 内容替换为以下代码
 window:

                ## This lays things out properly if history_height is None.
                has fixed:
                    yfit True

                if h.who:

                    label h.who:
                        style "history_name"
                        substitute False

                        ## Take the color of the who text from the Character, if
                        ## set.
                        if "color" in h.who_args:
                            text_color h.who_args["color"]

                $ what = renpy.filter_text_tags(h.what, allow=gui.history_allow_tags)
                textbutton what:                    
                    substitute False
                    style "history_text"
                    action Confirm("Jump?", yes=RollbackToIdentifier(h.rollback_identifier), no=None, confirm_selected=False), 
 

将原来的text组件替换为textbitton组件，点击历史记录中的对话，确认，即可跳转到目标对话。

水上由岐

现代GAL里非常实用的一个功能,感谢分享

龙氏

默认在 screens.rpy里搜索：screen history 进行修改。
完全替换 screen history(): 的脚本如下：

[RenPy] 纯文本查看 复制代码

screen history():

    tag menu

    ## Avoid predicting this screen, as it can be very large.
    predict False

    use game_menu(_("History"), scroll=("vpgrid" if gui.history_height else "viewport"), yinitial=1.0):

        style_prefix "history"

        for h in _history_list:

            window:
                ## This lays things out properly if history_height is None.
                has fixed:
                    yfit True

                if h.who:
                    label h.who:
                        style "history_name"
                        substitute False

                        ## Take the color of the who text from the Character, if set.
                        if "color" in h.who_args:
                            text_color h.who_args["color"]
                            
                $ what = renpy.filter_text_tags(h.what, allow=gui.history_allow_tags)
                textbutton what:
                    substitute False
                    style "history_text"
                    action Confirm("跳转到此处？", yes=RollbackToIdentifier(h.rollback_identifier), no=None, confirm_selected=False),

        if not _history_list:
            label _("The dialogue history is empty.")

乐西白

感谢分享！

不是心教

感谢老哥，十分好用

天使的遗族

这个跟跳到上一个选项比那个更常用？